Deploying .NET

This topic was edited by a BMC Contributor and has not been approved.  More information.

Contributor content

This topic was created by a BMC Contributor and has not been approved. More information.

The following sections discuss how to deploy .NET. Each section focuses on a specific version of .NET.

Deploying .NET 4.0

  1. Package your dotnetversion.exe as a custom software deployment (for example: dotNetFx40_Full_x86_x64.exe)
  2. In the Install command field, enter the following command:

    start /wait ??SOURCE?? /q /norestart
    

    Note

    Do not enclose ??SOURCE?? in quotes. If you do not remove the " " quotes, the installation will fail, as the quotes impact the /q that follows.

Deploying .NET 3.5 SP1 (Windows 2008 R2)

.Net is already packaged with Windows 2008 R2. Therefore, it has to be installed as a Role instead of as an executable, similar to IIS.

start /w dism /online /enable-feature /FeatureName:NetFx3

Note

This command is case-sensitive for the package name. Ensure that it is entered correctly as NetFx3.

Deploying .NET 3.5

The following sample script can be used to perform a full installation of .NET Framework 3.5. For more information about this sample script, see http://msdn.microsoft.com/en-us/library/cc160717.aspx. This script assumes that you are packaging dotnetfx35.exe and deploying it to c:\tmp\stage.

set WORKFOLDER=c:\tmp\stage
set dotNetFX35build=%WORKFOLDER%\dotnetfx35.exe
echo Creating Admin Install points for NETFX3 %PROCESSOR_ARCHITECTURE%

REM Create folders where work will be done
md %WORKFOLDER%\ext
md %WORKFOLDER%\AIP
md %WORKFOLDER%\logs
pushd %WORKFOLDER%

REM Extract the files from the NETFX35 redist SFX
call dotnetfx35.exe /q /x:%WORKFOLDER%\ext

REM ------------------------------------------------------------
REM create the MSXML6 x86 admin install point
md %WORKFOLDER%\AIP\MSXML6_x86
call msiexec /a %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX30\x86\msxml6.msi /qb /l*v %WORKFOLDER%\logs\MSXML6_x86.log Targetdir=%WORKFOLDER%\AIP\MSXML6_x86

REM create the MSXML6 x64 admin install point
md %WORKFOLDER%\AIP\MSXML6_x64
call msiexec /a %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX30\x64\msxml6.msi /qb /l*v %WORKFOLDER%\logs\MSXML6_x64.log Targetdir=%WORKFOLDER%\AIP\MSXML6_x64

REM ------------------------------------------------------------
REM create the RGBRAST x86 admin install point
md %WORKFOLDER%\AIP\RGBRAST_x86
call msiexec /a %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX30\RGB9RAST_x86.msi /qb /l*v %WORKFOLDER%\logs\RGBRAST_x86.log REBOOT=ReallySuppress Targetdir=%WORKFOLDER%\AIP\RGBRAST_x86

REM create the RGBRAST x64 admin install point
md %WORKFOLDER%\AIP\RGBRAST_x64
call msiexec /a %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX30\RGB9RAST_x64.msi /qb /l*v %WORKFOLDER%\logs\RGBRAST_x64.log REBOOT=ReallySuppress Targetdir=%WORKFOLDER%\AIP\RGBRAST_x64

REM ------------------------------------------------------------
REM Extract NETFX 35 x86 components
md %WORKFOLDER%\ext\netfx35_x86
call %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX35\x86\netfx35_x86.exe /q /x: %WORKFOLDER%\ext\netfx35_x86

REM Extract NETFX 35 x64 components
md %WORKFOLDER%\ext\netfx35_x64
call %WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX35\x64\netfx35_x64.exe /q /x: %WORKFOLDER%\ext\netfx35_x64

REM ------------------------------------------------------------
REM create the NETFX35 x86 admin install point
md %WORKFOLDER%\AIP\netfx35_x86
call msiexec /qb /a %WORKFOLDER%\ext\netfx35_x86\vs_setup.msi USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx35_x86.log TARGETDIR=%WORKFOLDER%\AIP\netfx35_x86

REM create the NETFX35 x64 admin install point
md %WORKFOLDER%\AIP\netfx35_x64
call msiexec /qb /a %WORKFOLDER%\ext\netfx35_x64\vs_setup.msi USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx35_x64.log TARGETDIR=%WORKFOLDER%\AIP\netfx35_x64


REM ------------------------------------------------------------
REM create the NETFX20 x86 SP1 admin install point

REM 2.0 SP1 files location
Set fx20=%WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX20\
md %WORKFOLDER%\AIP\NETFX20_x86
call msiexec /a %fx20%netfx20a_x86.msi /update %fx20%ASPNET.msp;%fx20%CLR.msp;%fx20%CRT.msp;%fx20%NetFX_CA.msp;%fx20%NetFX_Core.msp;%fx20%NetFX_Other.msp;%fx20%PreXP.msp;%fx20%WinForms.msp;%fx20%DW.msp USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx20_x86.log TARGETDIR=%WORKFOLDER%\AIP\NETFX20

REM create the NETFX20 x64 SP1 admin install point
md %WORKFOLDER%\AIP\NETFX20_x64
call msiexec /a %fx20%Netfx20a_x64.msi /update %fx20%ASPNET_64.msp;%fx20%CLR_64.msp;%fx20%CRT_64.msp;%fx20%DW_64.msp;%fx20%NetFX_Core_64.msp;%fx20%NetFX_Other_64.msp;%fx20%WinForms_64.msp;%fx20%ASPNET.msp;%fx20%CLR.msp;%fx20%CRT.msp;%fx20%NetFX_CA.msp;%fx20%NetFX_Core.msp;%fx20%NetFX_Other.msp;%fx20%PreXP.msp;%fx20%WinForms.msp;%fx20%DW.msp USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx20_x64.log TARGETDIR=%WORKFOLDER%\AIP\NETFX20_x64


REM ------------------------------------------------------------
REM create the NETFX30 SP1 x86 admin install point

REM 3.0 SP1 files location
Set fx30=%WORKFOLDER%\ext\wcu\dotNetFramework\dotNetFX30\
md %WORKFOLDER%\AIP\NETFX30_x86
call msiexec /a %fx30%netfx30a_x86.msi /update %fx30%WCF.msp;%fx30%WCS.msp;%fx30%WF.msp;%fx30%WPF1.msp;%fx30%WPF2.msp;%fx30%WPF_Other.msp;%fx30%XPS.msp;%fx30%WF_32.msp;%fx30%WPF2_32.msp;%fx30%WPF_Other_32.msp USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx30_x86.log TARGETDIR=%WORKFOLDER%\AIP\NETFX30_x64

REM create the NETFX30 SP1 x64 admin install point
md %WORKFOLDER%\AIP\NETFX30_x64
call msiexec /a %fx30%netfx30a_x64.msi /update %fx30%WCF.msp;%fx30%WCS.msp;%fx30%WF.msp;%fx30%WPF1.msp;%fx30%WPF2.msp;%fx30%WPF_Other.msp;%fx30%XPS.msp;%fx30%WCF_64.msp;%fx30%WCS_64.msp;%fx30%WF_64.msp;%fx30%WPF1_64.msp;%fx30%WPF2_64.msp;%fx30%WPF_Other_64.msp USING_EXUIH=1 REBOOT=ReallySuppress /l*v %WORKFOLDER%\logs\netfx30_x64.log TARGETDIR=%WORKFOLDER%\AIP\NETFX30_x64
Was this page helpful? Yes No Submitting... Thank you

Comments